Welcome to the wiki talking about FFmpeg on Windows.

Batch file for installing files of MinGW + MSYS

@REM ***************************************************************************
@REM
@REM Batch file for installing files of MinGW + MSYS
@REM
@REM Version: 1.2 @ August 28, 2011
@REM
@REM *** License ***
@REM
@REM Except where otherwise noted, all of the batchs and scripts are
@REM copyrighted by http://www.FFmpegWindows.org
@REM
@REM Copyright (C) 2010-2011 http://www.FFmpegWindows.org All rights reserved.
@REM
@REM These batchs and scripts are provided "as-is," without any express or
@REM implied warranty. In no event shall the author be held liable for any
@REM damages arising from the use of them.
@REM
@REM Permission is granted to anyone to use these batchs and scripts for
@REM any purpose, including commercial applications, and to alter and
@REM redistribute it, provided that the following conditions are met:
@REM
@REM 1. All redistributions of batchs and scripts must retain all copyright
@REM    notices that are currently in place, and this list of conditions
@REM    without modification.
@REM
@REM 2. Modified versions must be plainly marked as such, and must not be
@REM    misrepresented as being the original batchs and scripts.
@REM
@REM http://www.ffmpegwindows.org
@REM
@REM ***************************************************************************

@REM check if we are running within the main batch file
@IF NOT "%IN_MINGW_MSYS_BAT%"=="1" (
	@ECHO.
	@ECHO This batch file "%~NX0" needs to be called by the main batch file.
	@ECHO.
	@PAUSE
	@EXIT /B 1
)

REM global variables: INSTALL_DIR, FILE_NAME, FILE_VER
REM caller parameter %1: 7-Zip extracting parameters

REM installation logs directory
SET INSTALL_LOGS=%INSTALL_BASE%Install_Logs\

REM create installation directory
IF NOT EXIST "%INSTALL_DIR%" (
	MKDIR "%INSTALL_DIR%"
	IF ERRORLEVEL==1 (
		ECHO   Error: *failed* to create directory "%INSTALL_DIR%"
		PAUSE
		EXIT /B 1
	)
)
CD /D "%INSTALL_DIR%"

REM ignore when the file installed
IF EXIST "%INSTALL_LOGS%%FILE_NAME%.log" (
	ECHO   "%FILE_NAME%" had already been installed.
	EXIT /B 0
)

REM check the source file
IF NOT EXIST "%SAVE_DIR%%FILE_NAME%" (
	ECHO   File not found: "%FILE_NAME%"
	EXIT /B 0
)

REM the zip file
IF "%FILE_VER%"=="" (
	REM extract the zip file
	ECHO   Extracting "%FILE_NAME%" ...
	"%W7Z%" x -y %1 "%SAVE_DIR%%FILE_NAME%" > nul 2> nul
	IF ERRORLEVEL==1 (
		ECHO   Extracting "%FILE_NAME%" *failed*
		EXIT /B 0
	)
	ECHO   Extracting "%FILE_NAME%" done
	CALL :INSTALL_LOG
	EXIT /B 0
)

REM extract the tgz/lzma file
ECHO   Extracting "%FILE_NAME%" ...
"%W7Z%" x -y "%SAVE_DIR%%FILE_NAME%" > nul 2> nul
IF ERRORLEVEL==1 (
	ECHO   Extracting "%FILE_NAME%" *failed*
	EXIT /B 0
)
ECHO   Extracting "%FILE_NAME%" done

REM extract the tarball
CALL :EXTRACT_TAR %FILE_NAME% %1
 
EXIT /B 0

REM ***************************************************************************
 
:EXTRACT_TAR
ECHO     Extracting "%~N1" ...
"%W7Z%" x -y %2 "%INSTALL_DIR%%~N1" > nul 2> nul
IF ERRORLEVEL==1 (
	ECHO     Extracting "%~N1" *failed*
	EXIT /B 0
)
ECHO     Extracting "%~N1" done

REM delete the tarball
DEL "%INSTALL_DIR%%~N1"
 
:INSTALL_LOG
REM create installation logs directory
IF NOT EXIST "%INSTALL_LOGS%" (
	MKDIR "%INSTALL_LOGS%"
	IF ERRORLEVEL==1 (
		ECHO   Error: *failed* to create directory "%INSTALL_LOGS%"
		EXIT /B 0
	)
)

REM generate installation log
DATE /T > %INSTALL_LOGS%%FILE_NAME%.log
TIME /T >> %INSTALL_LOGS%%FILE_NAME%.log
 
EXIT /B 0